Dell Technologies – Examples

V1.0.4: Creating Multiple Volumes

Mon, 01 Jan 0001 00:00:00 +0000

You can use the for_each meta-argument to create multiple volumes.

Example

To create 3 different volumes using terraform_for_each using the following configuration:

resource "powermax_volume" "test" {
  for_each = toset(["vol_1", "vol_2", "vol_3"])
  vol_name = each.key
  size = 2.45
  sg_name = "terraform_sg"
  cap_unit = "GB"
}

You can use the count meta-argument to create multiple volumes.

Example

To create 3 different volumes using the following configuration:

resource "powermax_volume" "test" {
  count = 3
  vol_name = "terraform_volume-${count.index}"
  size = 2.45
  sg_name = "terraform_sg"
  cap_unit = "GB"
}

V1.0.4: Environment Variables

Mon, 01 Jan 0001 00:00:00 +0000

Environment Variables Overview

This Guide will describe two common ways on how to use environment variables with terraform. For more information you may check out the terraform docs directly.

Export or Directly Set During Terraform Command

This section will desribe how to pass in environment variables directly during the terraform command.

main.tf

// Create a variable which will be assigned during the command
variable "foo" {
  type = string
}

data "example_datasource" "all" {
  filter {
    // Reference that variable how you would normally in terraform 
    name = [var.foo]
  }
}

Using the above example, to set the environment variable for foo you must use the prefix of TF_VAR_ + the name of the variable i.e: TF_VAR_foo. This will translate to setting the variable during the command.

Example Command: TF_VAR_foo="example-name" terraform plan

Export and then run the terraform command

export TF_VAR_foo="example-name"

This will execute terraform plan with the value of example-name for the variable foo.

Using the External Terraform Provider

This section will describe how to use environment variables using the external terraform provider

env.sh

cat << EOF
{
 "foo": "test"
}
EOF

main.tf

terraform {
  required_providers {
    external = {
      source = "hashicorp/external"
      version = "2.3.4"
    }
  }
}

# Run the script to get the environment variables of interest.
# This is a datasource, so it will run at plan time.
data "external" "env" {
  program = ["bash", "env.sh"]
}

# Show the results of running the datasource. This is a map of environment
# variable names to their values.
output "env" {
  value = data.external.env.result
}

data "example_datasource" "all" {
  filter {
    name = [data.external.env.result["foo"]]
  }
}

In this example there are 2 files.

env.sh This creates the input for the environment variables you would like to pass into and use in the terraform configuration main.tf
main.tf this defines the external datasource which takes in the output from the external datasource and then it can be used in the example_datasource filter i.e data.external.env.result["foo"]

V1.0.4: How to use our Provider

Mon, 01 Jan 0001 00:00:00 +0000

This provider gives Terraform the ablility to work with a PowerMax Storage System. It can be used to manage many aspects of the PowerMax including hosts, host groups, masking views, port groups, snapshots, storage groups and volumes. For more information about each particular resource or datasource view those specific examples and documentation.

Below is an example of the PowerMax Provider and how to use it.

Example

The following example demonstrates basic usage of the provider to provision a volume to a storage group.

terraform {
  required_providers {
    powermax = {
      source = "dell/powermax"
    }
  }
}

provider "powermax" {
  username      = var.username
  password      = var.password
  endpoint      = var.endpoint
  serial_number = var.serial_number
  pmax_version  = var.pmax_version
  insecure      = true

  ## Provider can also be set using environment variables
  ## If environment variables are set it will override this configuration
  ## Example environment variables
  # POWERMAX_USERNAME="username"
  # POWERMAX_PASSWORD="password"
  # POWERMAX_ENDPOINT="https://yourhost.host.com:8443"
  # POWERMAX_SERIAL_NUMBER="xxxxxxxxxxxx"
  # POWERMAX_POWERMAX_VERSION="100"
  # POWERMAX_INSECURE="false"
}

resource "powermax_volume" "test" {

  # Required name of the volume to be created
  vol_name = "terraform_volume"

  # Required size of the volume
  size = 2.45

  # Required name of the storage group which the volume will be created with
  sg_name = "terraform_sg"

  # Optional Default Unit is GB
  # Possible units are MB, GB, TB, and CYL
  cap_unit = "GB"

  # Optional enable the mobility id 
  mobility_id_enabled = false

}

Refer to the specific provider and resource documetation for more information

Argument Reference

The following arguments are used to configure the provider

Required

endpoint (String) Schema + IP or FQDN + port IE: (https://x.x.x.x:8443) of the PowerMax host
password (String, Sensitive) The password of the PowerMax host.
pmax_version (String) The version of the PowerMax host.
serial_number (String) The serial_number of the PowerMax host.
username (String) The username of the PowerMax host.

Optional

insecure (Boolean) Boolean variable to specify whether to validate SSL certificate or not.

Bug Reports and Contributing

If you need to sumbit a bug please do so on our github issues page https://github.com/dell/terraform-provider-powermax/issues If you would like to contribute please follow the README here: https://github.com/dell/terraform-provider-powermax