Dell Technologies – Examples

V1.9.0:

Mon, 01 Jan 0001 00:00:00 +0000

ESXi SDC End to End Example

Overview

This guide will give the steps in order to install and being to use a PowerFlex SDC in the vSphere context.

It will give examples of the following:

Install the SDC on an ESXi Host
Create and Attach a Volume to an SDCs
Create VMFS Datastoures based on the Attached volumes

Step 1: Install the SDC on ESXi Host

1.1 Setup Provider.tf

Fill in username, password, and endpoint ip/hostname

provider.tf

terraform {
   required_providers {
     powerflex = {
       version = ">=1.6.0"
       source  = "registry.terraform.io/dell/powerflex"
     }
   }
 }


provider "powerflex" {
  username = var.username
  password = var.password
  endpoint = var.endpoint
  insecure = true
  timeout  = 120
}


// Variables
variable "username" {
  type        = string
  description = "Stores the username of PowerFlex host."
}

variable "password" {
  type        = string
  description = "Stores the password of PowerFlex host."
}

variable "endpoint" {
  type        = string
  description = "Stores the endpoint of PowerFlex host. eg: https://10.1.1.1:443, here 443 is port where API requests are getting accepted"
}

1.2 Download the SDC Packages

Download the SDC Packages from Dell Support.

We support installing SDC on Windows ESXi and Linux Hosts. In this example we will use the ESXi sdc_host terraform resource to do the install of an SDC an ESXi host. For more examples check out (https://dell.github.io/terraform-docs/docs/storage/platforms/powerflex/product_guide/resources/sdc_host/).

1.3 Install the SDC on ESXi Host


# # generate a random guid. This is required only for ESXi hosts.
resource "random_uuid" "sdc_guid" {
}

resource "powerflex_sdc_host" "sdc" {
  ip = "10.10.10.10" // The ESXi Host IP
  remote = {
    user = var.esxi-host-username
    password = var.esxi-host-password
  }
  os_family = "esxi"
  esxi = {
    //We generate one using terraform `random_guid` resource above but it should look something like this: "12345678-90AB-CDEF-1234-567890ABCDEF"
    guid = random_uuid.sdc_guid.result
  }
  name         = var.sdc-name
  package_path = var.sdc-path
  // Always just set this to false
  use_remote_path = false
}

variable "sdc-name" {
  type        = string
  description = "Stores the name of the SDC."
  default = "current-user-sdc-esxi"
}

variable "sdc-path" {
  type        = string
  description = "Stores the path to where you downloaded the sdc ESXi package if in this directory then should looks something like './sdc-4.5.0.263-esx8.x.zip'"
}

variable "esxi-host-username" {
  type        = string
  description = "Stores the username of ESXi host."
}

variable "esxi-host-password" {
  type        = string
  description = "Stores the password of the ESXi host."
}

Step 2: Create and Attach Volume

2.1 Fill in the provider config

Fill in username, password, and endpoint ip/hostname

provider.tf

terraform {
   required_providers {
     powerflex = {
       version = ">=1.6.0"
       source  = "registry.terraform.io/dell/powerflex"
     }
   }
 }


provider "powerflex" {
  username = var.username
  password = var.password
  endpoint = var.endpoint
  insecure = true
  timeout  = 120
}


// Variables
variable "username" {
  type        = string
  description = "Stores the username of PowerFlex host."
}

variable "password" {
  type        = string
  description = "Stores the password of PowerFlex host."
}

variable "endpoint" {
  type        = string
  description = "Stores the endpoint of PowerFlex host. eg: https://10.1.1.1:443, here 443 is port where API requests are getting accepted"
}

2.2 Create the Volume

resource "powerflex_volume" "volume-create" {
  name = var.name

  # To create / update, either protection_domain_id or protection_domain_name must be provided
  protection_domain_name = var.protection_domain_name

  # To create / update, either storage_pool_id or storage_pool_name must be provided
  storage_pool_name = var.storage_pool_name

  # The unit of size of the volume is defined by capacity_unit whose default value is "GB".
  size          = var.size
  capacity_unit = var.capacity_unit # GB/TB

  use_rm_cache = var.use_rm_cache # true/false
  volume_type  = var.volume_type # ThickProvisioned/ThinProvisioned volume type
  access_mode  = var.access_mode # ReadWrite/ReadOnly volume access mode
  remove_mode  = var.remove_mode # INCLUDING_DESCENDANTS/ONLY_ME remove mode
}

// Variables

variable "name" {
  type        = string
  description = "name of the Powerflex Volume"
}

variable "protection_domain_name" {
  type        = string
  description = "protection_domain name of the Powerflex Volume"
}

variable "storage_pool_name" {
  type        = string
  description = "storage_pool name of the Powerflex Volume"
}

variable "size" {
  type        = number
  description = "size of the Powerflex Volume"
  default = 8
}

variable "capacity_unit" {
  type        = string
  description = "Capacity Unit of the Powerflex Volume Options:(GB/TB)"
  default = "GB"
}

variable "use_rm_cache" {
  type        = bool
  description = "Sets the rm_cache option of the Powerflex Volume"
  default = true
}

variable "volume_type" {
  type        = string
  description = "Volume Type of the Powerflex Volume Options:(ThickProvisioned/ThinProvisioned)"
  default = "ThickProvisioned"
}

variable "access_mode" {
  type        = string
  description = "Access Mode of the Powerflex Volume Options:(ReadWrite/ReadOnly)"
  default = "ReadWrite"
}

variable "remove_mode" {
  type        = string
  description = "Remove Mode of the Powerflex Volume Options:(INCLUDING_DESCENDANTS/ONLY_ME)"
  default = "INCLUDING_DESCENDANTS"
}

2.3 Attach the Volume to the SDC

Grab the SDC ID using the sdc datasource, then map the newly created volume to the SDC

data "powerflex_sdc" "filtered" {
  filter {
    name = [var.sdc_name]
  }
}

resource "powerflex_sdc_volumes_mapping" "mapping-test" {
  # SDC id
  id = data.powerflex_sdc.filtered.sdcs[0].id
  volume_list = [
    {
      # id of the volume which needs to be mapped. 
      # either volume_id or volume_name can be used.
      volume_id = resource.powerflex_volume.volume-create.id

      # Valid values are 0 or integers greater than 10
      limit_iops = var.limit_iops

      # Default value is 0
      limit_bw_in_mbps = var.limit_bw_in_mbps

      access_mode = var.access_mode # ReadOnly/ReadWrite/NoAccess
    }
  ]
}


// Variables
variable "sdc_name" {
  type        = string
  description = "name of the sdc"
}

variable "limit_iops" {
  type        = number
  description = "limit_iops Valid values are 0 or integers greater than 10"
  default = 140
}

variable "limit_bw_in_mbps" {
  type        = number
  description = "limit_bw_in_mbps Default value is 0"
  default = 0
}

variable "access_mode" {
  type        = string
  description = "access_mode Options(ReadOnly/ReadWrite/NoAccess)"
  default = "ReadOnly"
}

Step 3: Create VMFS Datasource

3.1 Setup the vSphere provider

terraform {
  required_providers {
    vsphere = {
      source = "hashicorp/vsphere"
      version = "2.11.1"
    }
  }
}

provider "vsphere" {
  user                 = var.vsphere_user
  password             = var.vsphere_password
  vsphere_server       = var.vsphere_server
  allow_unverified_ssl = var.allow_unverified_ssl
  api_timeout          = 100
}

// Variables
variable "vsphere_user" {
  type        = string
  description = "Stores the username of vsphere_user."
}

variable "vsphere_password" {
  type        = string
  description = "Stores the password of vsphere_password."
}

variable "vsphere_server" {
  type        = string
  description = "Stores the host ip/fqdn of the vsphere_server."
}

variable "allow_unverified_ssl" {
  type        = string
  description = "Allow unverified ssl connection"
  default = true
}

3.2 Rescan and Create the VMFS Datastore

data "vsphere_datacenter" "datacenter" {
  name = "Datacenter"
}

data "vsphere_host" "host" {
  name          = var.host_name // Hosts name in vSphere 
  datacenter_id = data.vsphere_datacenter.datacenter.id
}

data "vsphere_vmfs_disks" "available" {
  host_system_id = data.vsphere_host.host.id
  rescan         = true
  filter = var.vmfs_filter // Should look something like eui.bcc545a72b516e0fa45627070000000e
}

resource "vsphere_vmfs_datastore" "datastore" {
  name           = var.vmfs_datastore_name // name of vmfs datastore to be created
  host_system_id = data.vsphere_host.host.id

  disks = "${data.vsphere_vmfs_disks.available.disks}"
}

// Variables
variable "host_name" {
  type        = string
  description = "Stores the name of the vSphere host."
}

variable "vmfs_filter" {
  type        = string
  description = "The filter which is used to grab the disk name to create the VMFS datasource upon. Starts with `eui.`. If you want a specific disk give full eui value, example: `eui.bcc545a72b516e0fa45627070000000e`. Otherwise the default will grab all disks with the eui path on the Powerflex Storage Adaptor"
  default = "eui."
}

variable "vmfs_datastore_name" {
  type        = string
  description = "The name used when creating the VMFS datastore"
  default = "terraform-vmfs-datastore"
}

V1.9.0:

Mon, 01 Jan 0001 00:00:00 +0000

SDC End to End Example

Overview

This guide will give the steps in order to install and being to use a PowerFlex SDC.

It will give examples of the following:

Deploy the SDC Linux Virtual Machine (vSphere)
Install the SDC
Create and Attach a Volume to an SDCs

Step 1: VM Deployment

There are many way in which you can deploy a Virtual Machine. Below is an approch using the vSphere terraform provider. If your team use a different hypervisor, or has a differnt process for creating the VMs this step can just be skipped. The examples below show how to use the vSphere terraform provider but for more information you can check out there documentaion: https://registry.terraform.io/providers/hashicorp/vsphere/latest

1.1 Use the vSphere provider and Setup provider.tf

Provider Example:

Fill in username, password, vsphere_server ip/hostname

provider.tf

terraform {
  required_providers {
    vsphere = {
      source = "hashicorp/vsphere"
      version = "2.8.2"
    }
  }
}

provider "vsphere" {
  user                 = var.vsphere_user
  password             = var.vsphere_password
  vsphere_server       = var.vsphere_server
  allow_unverified_ssl = var.allow_unverified_ssl
  api_timeout          = 10
}


// Variables
variable "vsphere_user" {
  type        = string
  description = "Stores the username of vsphere_user."
}

variable "vsphere_password" {
  type        = string
  description = "Stores the password of vsphere_password."
}

variable "vsphere_server" {
  type        = string
  description = "Stores the host ip/fqdn of the vsphere_server."
}

variable "allow_unverified_ssl" {
  type        = string
  description = "Allow unverified ssl connection"
  default = true
}

1.2 Gather Needed Data

Using vSphere Terraform Datasources for datacenter, datastore, resource_pool, host and network, we need to gather all of the information needed to create the virtual machine

Example:

datasources.tf

data "vsphere_datacenter" "datacenter" {
  name = var.vsphere_datacenter_name
}

data "vsphere_datastore" "datastore" {
  name = var.vsphere_datastore_name
  datacenter_id = data.vsphere_datacenter.datacenter.id
}

data "vsphere_resource_pool" "pool" {
  name = var.vsphere_resource_pool_name
  datacenter_id = data.vsphere_datacenter.datacenter.id
}

data "vsphere_host" "host" {
  name = var.vsphere_host_name
  datacenter_id = data.vsphere_datacenter.datacenter.id
}

data "vsphere_network" "network" {
  name = var.vsphere_network_name
  datacenter_id = data.vsphere_datacenter.datacenter.id
}


// Variables
variable "vsphere_datacenter_name" {
  type = string
  description = "The name of the datacenter in which to deploy the virtual machines."
}

variable "vsphere_datastore_name" {
  type = string
  description = "The name of the vSphere datastore in which to deploy the virtual machines."
}

variable "vsphere_network_name" {
  type = string
  description = "The name of the vSphere datastore in which to deploy the virtual machines."
}

variable "vsphere_resource_pool_name" {
  type = string
  description = "The name of the vSphere resource pool in which to deploy the virtual machines."
}

variable "vsphere_host_name" {
  type = string
  description = "The name of the vSphere host in which to deploy the virtual machines."
}

1.3 Deploy the Virtual Machine

You can deploy one of two ways using a .ova image or using a vsphere template. Here is an examples of both.

Note: VM should have the following packages installed fio sshpass unzip yum-utils wget

.ova Example:

Note: the vapp properties will need to be filled out based on each usecase as it will be different in each environment

resource "vsphere_virtual_machine" "vm-installer" {
  name = var.vm_name
  datacenter_id = data.vsphere_datacenter.datacenter.id
  datastore_id         = data.vsphere_datastore.datastore.id
  host_system_id       = data.vsphere_host.host.id
  resource_pool_id = data.vsphere_resource_pool.pool.id

  num_cpus = var.num_cpus
  memory = var.memory
  wait_for_guest_net_timeout = 0
  wait_for_guest_ip_timeout  = 0

  network_interface {
    network_id = data.vsphere_network.network.id
    adapter_type = var.adapter_type 
  }

  ovf_deploy {
    allow_unverified_ssl_cert = var.allow_unverified_ssl
    remote_ovf_url = var.vm_ova_path
    disk_provisioning = var.disk_provisioning
    ip_protocol = var.ip_protocol
    ip_allocation_policy = var.ip_allocation_policy

    ovf_network_map = {
      network_id = data.vsphere_network.network.id
    }
  }

  // Depends on the image you need to fill out for your specific case/ova image you are using
  vapp {
    properties = {
      "guestinfo.hostname"     = "remote-foo.example.com",
      "guestinfo.ipaddress"    = "172.16.11.101",
      "guestinfo.netmask"      = "255.255.255.0",
      "guestinfo.gateway"      = "172.16.11.1",
      "guestinfo.dns"          = "172.16.11.4",
      "guestinfo.domain"       = "example.com",
      "guestinfo.ntp"          = "ntp.example.com",
      "guestinfo.password"     = "VMware1!",
      "guestinfo.ssh"          = "True"
    }
  }
}


// Variables

variable "vm_name" {
    type = string
    description = "Name of the PFMP installer VM, default to `new_terraform_vm`"
    default = "new_terraform_sdc_vm"
}

variable "disk_provisioning" {
  type = string
  description = "The disk provisioning type for the virtual machine. Options (thin, flat, think, sameAsSource) defaults to `thin`"
  default = "thin"
}

variable "ip_protocol" {
  type = string
  description = "The IP protocol for the virtual machine. Defaults to `IPV4`"
  default = "IPV4"
}

variable "ip_allocation_policy" {
  type = string
  description = "The IP allocation policy for the virtual machine. Defaults to `STATIC_MANUAL`"
  default = "STATIC_MANUAL"
}

variable "num_cpus" {
  type = number
  description = "Number of CPUs for the virtual machine. Defaults to `1`"
  default = 1
}

variable "memory" {
  type = number
  description = "Memory for the virtual machine. Defaults to `4060`"
  default = 4060
}

variable "adapter_type" {
  type = string
  description = "Network Adapter Type for the virtual machine. Defaults to `vmxnet3` Options can be found here: https://docs.vmware.com/en/VMware-vSphere/7.0/com.vmware.vsphere.vm_admin.doc/GUID-AF9E24A8-2CFA-447B-AC83-35D563119667.html"
  default = "vmxnet3"
}

Template Example:

data "vsphere_virtual_machine" "template_example" {
  name          = "linux-template"
  datacenter_id = data.vsphere_datacenter.datacenter.id
}

resource "vsphere_virtual_machine" "template" {

  name             = var.vm_name
  resource_pool_id = data.vsphere_resource_pool.pool.id
  datastore_id     = data.vsphere_datastore.primary_datastore.id
  num_cpus         = var.num_cpus
  memory           = var.memory
  folder           = var.vmfolder
  guest_id         = data.vsphere_virtual_machine.template_example.guest_id
  scsi_type        = data.vsphere_virtual_machine.template_example.scsi_type
  scsi_controller_count = 4
  firmware         = "efi"

  network_interface {
    network_id   = data.vsphere_network.VM_Network.id
    adapter_type = data.vsphere_virtual_machine.template_example.network_interface_types[0]
  }

  wait_for_guest_net_timeout  = 10000000000000000
  wait_for_guest_net_routable = false
  wait_for_guest_ip_timeout   = 10000000000000000
  shutdown_wait_timeout       = 10
  migrate_wait_timeout        = 10000000000000000
  force_power_off             = false

  disk {
    label            = "OS"
    size             = 40
    thin_provisioned = data.vsphere_virtual_machine.template_example.disks.0.thin_provisioned
    unit_number      = 0
  }

  clone {
    template_uuid = data.vsphere_virtual_machine.template_example.id
    customize {
      linux_options {
        host_name = var.hostname
        domain    = var.dns[0]
      }
      network_interface {
        ipv4_address = var.mgmt_ip
        ipv4_netmask = 22
      }
      ipv4_gateway = var.gw
      dns_server_list = var.dns
      dns_suffix_list = var.search_domains
    }
  }


// Variables
variable "vm_name" {
    type = string
    description = "Name of the PFMP installer VM, default to `new_terraform_vm`"
    default = "new_terraform_sdc_vm"
}

variable "num_cpus" {
  type = number
  description = "Number of CPUs for the virtual machine. Defaults to `1`"
  default = 1
}

variable "memory" {
  type = number
  description = "Memory for the virtual machine. Defaults to `4060`"
  default = 4060
}

variable "search_domains" {
  type        = list(string)
  description = "List of DNS search domains"
}

variable "dns" {
  type = list(string)
}

variable "gw" {
  type = string
}

variable "vmfolder" {
  description = "Name of Folder to Deploy VM to"
}

variable "mgmt_ip" {
  description = "IP on Management Network"
  type        = string
}

Step 2: SDC Install

We support installing SDC on Windows EXSi and Linux Hosts. In this example we will use the linux sdc terraform module to do the install on the linux VM you have created above. For more examples including EXSi and Windows look here.

2.1 Download the SDC Packages

Download the SDC Packages from Dell Support. Once downloaded add the sdc package to an http or ftp site for easy access when deploying sdcs

2.2 Install the SDC

Fill in username, password, and endpoint ip/hostname

provider.tf

terraform {
   required_providers {
     powerflex = {
       version = ">=1.6.0"
       source  = "registry.terraform.io/dell/powerflex"
     }
   }
 }


provider "powerflex" {
  username = var.username
  password = var.password
  endpoint = var.endpoint
  insecure = true
  timeout  = 120
}


// Variables
variable "username" {
  type        = string
  description = "Stores the username of PowerFlex host."
}

variable "password" {
  type        = string
  description = "Stores the password of PowerFlex host."
}

variable "endpoint" {
  type        = string
  description = "Stores the endpoint of PowerFlex host. eg: https://10.1.1.1:443, here 443 is port where API requests are getting accepted"
}

Example Module:

module "modules_example_sdc_host_linux" {
  source  = "dell/modules/powerflex//examples/sdc_host_linux"
  version = "1.2.0"

  remote_host = {
    user = var.remote_user
    password = var.remote_password
    // If you have a ssh key and certificate.
    // You are able to use those instead of user/pass
    //private_key = ""
    //certificate = ""
  }

  ip = var.ip

  versions = versions={
    pflex =  var.sdc_pflex_version  //"4.5.3000.118"
    kernel = var.linux_kernal_version //"5.15.0-1-generic"
  }
  
  scini = {
    linux_distro = "RHEL9" #"Ubuntu"
    autobuild_scini = true
    // If autobuild is equal to false, give the path to your scini.ko or scini.rpm else this is not needed
    //url = "http://example.com/release/5.15.0-1-generic"
  }

  sdc_pkg = {
    url = var.package_url
    // Do not change this value
    remote_pkg_name = var.remote_pkg_name
    remote_file = var.package_name
    use_remote_path = true
    skip_download_sdc = true
  }
  mdm_ips = var.mdm_ips
}


// Variables
variable "ip" {
  type        = string
  description = "Stores the IP address of the remote Linux host."
}

variable "package_url" {
  type        = string
  description = "URL to where the SDC Package is located for download. This package will be downloaded directly onto the virtual machine. Example: http://example.com/EMC-ScaleIO-sdc-3.6-700.103.Ubuntu.22.04.x86_64.tar, ftp://username:password@ftpserver/path/to/file"
}

variable "remote_pkg_name" {
  type        = string
  description = "The name of the package. Example: emc-sdc-package.tar (for Ubuntu) emc-sdc-package.rpm (for RHEL)"
  default = "emc-sdc-package.tar"
}

variable "package_name" {
  type        = string
  description = "The name of the package. Example: EMC-ScaleIO-sdc-4.5-3000.118.Ubuntu.22.04.x86_64.tar (for Ubuntu) EMC-ScaleIO-sdc-4.5-3000.118.Ubuntu.22.04.x86_64.rpm (for RHEL)"
}

variable "remote_user" {
  type        = string
  description = "Stores the username of the remote Linux host."
}

variable "remote_password" {
  type        = string
  description = "Stores the password of the remote Linux host."
}

variable "sdc_pflex_version" {
  type        = string
  description = "The version of the powerflex sdc you are installing, this can be grabbed from the sdc package name i.e: PowerFlex_4.5.2100.105_Ubuntu18.04_SDC.tar the version would be 4.5.2100.105"
}

variable "linux_kernal_version" {
  type        = string
  description = "The version of linux we are using"
}

variable "mdm_ips" {
  description = "all the mdms (either primary,secondary or virtual ips) in a comma separated list by cluster. If sdc is only being connected to one powerflex leave this unset and it will use the mdms of the cluster set of the provider by default"
  type        = list(string)
  default = []
}

Step 3: Create and Attach Volume

3.1 Fill in the provider config

Fill in username, password, and endpoint ip/hostname

provider.tf

terraform {
   required_providers {
     powerflex = {
       version = ">=1.6.0"
       source  = "registry.terraform.io/dell/powerflex"
     }
   }
 }


provider "powerflex" {
  username = var.username
  password = var.password
  endpoint = var.endpoint
  insecure = true
  timeout  = 120
}


// Variables
variable "username" {
  type        = string
  description = "Stores the username of PowerFlex host."
}

variable "password" {
  type        = string
  description = "Stores the password of PowerFlex host."
}

variable "endpoint" {
  type        = string
  description = "Stores the endpoint of PowerFlex host. eg: https://10.1.1.1:443, here 443 is port where API requests are getting accepted"
}

3.2 Create the Volume

resource "powerflex_volume" "volume-create" {
  name = var.name

  # To create / update, either protection_domain_id or protection_domain_name must be provided
  protection_domain_name = var.protection_domain_name

  # To create / update, either storage_pool_id or storage_pool_name must be provided
  storage_pool_name = var.storage_pool_name

  # The unit of size of the volume is defined by capacity_unit whose default value is "GB".
  size          = var.size
  capacity_unit = var.capacity_unit # GB/TB

  use_rm_cache = var.use_rm_cache # true/false
  volume_type  = var.volume_type # ThickProvisioned/ThinProvisioned volume type
  access_mode  = var.access_mode # ReadWrite/ReadOnly volume access mode
  remove_mode  = var.remove_mode # INCLUDING_DESCENDANTS/ONLY_ME remove mode
}

// Variables

variable "name" {
  type        = string
  description = "name of the Powerflex Volume"
}

variable "protection_domain_name" {
  type        = string
  description = "protection_domain name of the Powerflex Volume"
}

variable "storage_pool_name" {
  type        = string
  description = "storage_pool name of the Powerflex Volume"
}

variable "size" {
  type        = number
  description = "size of the Powerflex Volume"
  default = 8
}

variable "capacity_unit" {
  type        = string
  description = "Capacity Unit of the Powerflex Volume Options:(GB/TB)"
  default = "GB"
}

variable "use_rm_cache" {
  type        = bool
  description = "Sets the rm_cache option of the Powerflex Volume"
  default = true
}

variable "volume_type" {
  type        = string
  description = "Volume Type of the Powerflex Volume Options:(ThickProvisioned/ThinProvisioned)"
  default = "ThickProvisioned"
}

variable "access_mode" {
  type        = string
  description = "Access Mode of the Powerflex Volume Options:(ReadWrite/ReadOnly)"
  default = "ReadWrite"
}

variable "remove_mode" {
  type        = string
  description = "Remove Mode of the Powerflex Volume Options:(INCLUDING_DESCENDANTS/ONLY_ME)"
  default = "INCLUDING_DESCENDANTS"
}

3.3 Attach the Volume to the SDC

Grab the SDC ID using the sdc datasource, then map the newly created volume to the SDC

data "powerflex_sdc" "filtered" {
  filter {
    name = [var.sdc_name]
  }
}

resource "powerflex_sdc_volumes_mapping" "mapping-test" {
  # SDC id
  id = data.powerflex_sdc.filtered.sdcs[0].id
  volume_list = [
    {
      # id of the volume which needs to be mapped. 
      # either volume_id or volume_name can be used.
      volume_id = resource.powerflex_volume.volume-create.id

      # Valid values are 0 or integers greater than 10
      limit_iops = var.limit_iops

      # Default value is 0
      limit_bw_in_mbps = var.limit_bw_in_mbps

      access_mode = var.access_mode # ReadOnly/ReadWrite/NoAccess
    }
  ]
}


// Variables
variable "sdc_name" {
  type        = string
  description = "name of the sdc"
}

variable "limit_iops" {
  type        = number
  description = "limit_iops Valid values are 0 or integers greater than 10"
  default = 140
}

variable "limit_bw_in_mbps" {
  type        = number
  description = "limit_bw_in_mbps Default value is 0"
  default = 0
}

variable "access_mode" {
  type        = string
  description = "access_mode Options(ReadOnly/ReadWrite/NoAccess)"
  default = "ReadOnly"
}

V1.9.0: Creating Multiple Volumes with Count

Mon, 01 Jan 0001 00:00:00 +0000

You can use the count meta-argument to create multiple volumes.

Example

To create 7 different volumes using the following configuration:

resource "powerflex_volume" "volumes" {
  count                  = 7
  name                   = "security-footage-${count.index}"
  protection_domain_name = "domain1"
  storage_pool_name      = "pool1"
  size                   = 8
  use_rm_cache           = true
  volume_type            = "ThinProvisioned"
  access_mode            = "ReadWrite"
}

V1.9.0: Creating Multiple Volumes with For Each

Mon, 01 Jan 0001 00:00:00 +0000

You can use the for_each meta-argument to create multiple volumes.

Example

To create 3 different volumes use the following configuration:

resource "powerflex_volume" "volume_example" {
  for_each = toset( ["Volume1", "Volume2", "Volume3"] )
  name = each.key
  protection_domain_name = "domain1"
  storage_pool_name = "pool1"
  size          = 8
  capacity_unit = "GB"
}

V1.9.0: Datasource Filtering

Mon, 01 Jan 0001 00:00:00 +0000

Datasource Filtering Overview

This describes how filtering works in the Powerflex Provider with a datasource filter block

The input below will be used showcase different scenarios and how they will work in our provider:

[
  {
   id = "id-1"
   field = false
   count = 1
  },
  {
   id = "id-2"
   field = true
   count = 2
  },
  {
   id = "id-3"
   field = true
   count = 3
  }
]

1. If a single filter field is set, filter and only return those values

Config:

data "powerflex_example_datasource" "exampleFilter" {
  filter {
   id = ["id-1", "id-2"]
  }
}

Output:

[
  {
   id = "id-1"
   field = false
   count = 1
  },
  {
   id = "id-2"
   field = true
   count = 2
  }
]

2. If multiple filters are set then it is the intersection of those filters:

Config:

data "powerflex_example_datasource" "exampleFilter" {
  filter {
   id = ["id-1", "id-2"]
   count = [2]
  }
}

Output:

[
  {
   id = "id-2"
   field = true
   count = 2
  }
]

3. If there are no intersection then the output will be empty:

Config:

data "powerflex_example_datasource" "exampleFilter" {
  filter {
   id = ["id-1", "id-2"]
   count = [3]
  }
}

Output:

[]

4. If the filter value is invalid then the output will be empty:

Config:

data "powerflex_example_datasource" "exampleFilter" {
  filter {
   id = ["invaid-id"]
  }
}

Output:

[]

5. If the filter value is using regular expressions:

Config:

data "powerflex_example_datasource" "exampleFilter" {
  filter {
   id = ["^id-[1-2]$"]
  }
}

Output:

[
   {
   id = "id-1"
   field = false
   count = 1
  },
  {
   id = "id-2"
   field = true
   count = 2
  }
]

V1.9.0: Deploying a PowerFlex cluster using a CSV Topology File

Mon, 01 Jan 0001 00:00:00 +0000

Deploying a PowerFlex cluster using a CSV Topology File

This guide explains how to use CSV file(s) for managing PowerFlex cluster via Terraform’s Cluster Resource.

Example

Note: It is recommended to use 2 separate csv files for cluster node related information and storage pool related information. Refer the following examples for more information. The first row will be treated as header.

cluster_node.csv

IPs,Username,Password,Operating System,Is MDM/TB,Is SDS,SDS Storage Device List,Is SDC,Is SDT
10.76.60.1,root,Password1,linux,Primary,Yes,/dev/sdb,Yes,Yes
10.76.60.2,root,Password1,linux,Secondary,Yes,/dev/sdb,Yes,Yes
10.76.60.3,root,Password1,linux,TB,Yes,/dev/sdb,Yes,Yes
10.76.60.4,root,Password1,linux,,Yes,/dev/sdb,Yes,Yes

sp_data.csv

ProtectionDomain,StoragePool,Media Type,Replication journal capacity percentage
domain_1,pool1,HDD,50

To perform SDC operations with a CSV file, use the following configuration:


locals {
  cluster_node_data = csvdecode(file("cluster_node.csv"))
  sp_data = csvdecode(file("sp_data.csv"))
}

resource "powerflex_cluster" "test" {
  # Security Related Fields
  mdm_password = "Password"
  lia_password = "Password"

  # Advance Security Configuration
  allow_non_secure_communication_with_lia = false
  allow_non_secure_communication_with_mdm = false
  disable_non_mgmt_components_auth = false

  # Cluster Configuration related fields
  cluster = [
    for row in local.cluster_node_data : {
      ips                  = row.IPs
      username             = row.Username
      password             = row.Password
      operating_system     = row["Operating System"]
      is_mdm_or_tb         = row["Is MDM/TB"]
      is_sds               = row["Is SDS"]
      sdc_name             = row["SDS Name"]
      perf_profile_for_sdc = row.perfProfileForSDC
      is_rfcache           = row["RFcache"]
      is_sdr               = row["Is SDR"]
      is_sdt               = row["Is SDT"]
    }
    if row["Is MDM/TB"] != "" # Validates if MDM role is not empty string
  ]

  storage_pools = [
    for row in local.sp_data : {
      media_type                              = row["Media Type"]
      protection_domain                       = row.ProtectionDomain
      storage_pool                            = row.StoragePool
      replication_journal_capacity_percentage = tonumber(row["Replication journal capacity percentage"])
    }
  ]
}

This Terraform configuration sets up a PowerFlex cluster by defining its configuration, including security settings, node information, and storage pool details. The data for this configuration is read from two CSV files using the csvdecode function and organized into the required format for the resource.

Proposed: Two Terraform local variables are getting declared here (cluster_node_data and sp_data) by using Terraform’s built-in ‘csvdecode’ function.

locals: The scope of the variable is within the configuration file. These variables are used to store data or perform calculations within this configuration.

cluster_node_data: Reads and decodes the CSV file “cluster_node.csv” into a list of maps. This file contains information about cluster nodes.

sp_data: Reads and decodes the CSV file “sp_data.csv” into a list of maps. This file contains information about storage pools.

cluster: A list variable which is getting created using a for loop which iterates over each element in the ‘cluster_node_data’ (local list variable).

storage_pools: A list variable which is getting created using a for loop which iterates over each element in the ‘sp_data’ (local list variable defined earlier).

The fields inside the object (e.g., ip, password, operating_system, etc.) are populated with values from the CSV file. You can also apply some conditions in the if statement to filter out rows where IPs and Password are not empty and not equal to “null.”

V1.9.0: Deploying a PowerFlex cluster using multiple values for mdm_ips

Mon, 01 Jan 0001 00:00:00 +0000

Deploying a PowerFlex cluster having multiple values for mdm_ips

This guide explains how to deploy a cluster which has multiple values for mdm_ips.

Example


resource "powerflex_cluster" "test" {
  mdm_password = "Password"
  lia_password = "Password"

  # Advance Security Configuration
  allow_non_secure_communication_with_lia = false
  allow_non_secure_communication_with_mdm = false
  disable_non_mgmt_components_auth        = false

  # Cluster Configuration related fields
  cluster = [
    {
      # MDM Configuration Fields
      username                 = "user",
      password                 = "password",
      operating_system         = "linux",
      is_mdm_or_tb             = "Primary",
      mdm_ips                  = "10.10.10.1,10.10.10.2,10.10.10.3",
      mdm_mgmt_ip              = "10.10.10.1",
      mdm_name                 = "mdm1",
      perf_profile_for_mdm     = "HighPerformance",
      virtual_ips              = "10.10.10.4,10.10.10.5",
      virtual_ip_nics          = "eth1,eth2",
      is_sds                   = "Yes",
      sds_name                 = "sds1",
      sds_all_ips              = "10.10.10.2,10.10.10.3",
      protection_domain        = "domain_1",
      sds_storage_device_list  = "/dev/sdb",
      sds_storage_device_names = "sdb",
      storage_pool_list        = "pool1",
      perf_profile_for_sds     = "HighPerformance",
      is_sdc                   = "Yes",
      sdc_name                 = "sdc1",
      perf_profile_for_sdc     = "HighPerformance"
      is_sdt                   = "Yes",
      sdt_name                 = "sdt1",
      sdt_all_ips              = "10.10.10.2,10.10.10.3",
    },
    {
      username                 = "user",
      password                 = "password",
      operating_system         = "linux",
      is_mdm_or_tb             = "Secondary",
      mdm_name                 = "mdm2",
      mdm_ips                  = "10.10.10.6,10.10.10.7,10.10.10.8",
      mdm_mgmt_ip              = "10.10.10.6",
      perf_profile_for_mdm     = "HighPerformance",
      virtual_ips              = "10.10.10.4,10.10.10.5",
      virtual_ip_nics          = "eth1,eth2",
      is_sds                   = "Yes",
      sds_name                 = "sds2",
      sds_all_ips              = "10.10.10.7,10.10.10.8",
      sds_storage_device_list  = "/dev/sdb",
      sds_storage_device_names = "sdb",
      protection_domain        = "domain_1",
      storage_pool_list        = "pool1",
      perf_profile_for_sds     = "HighPerformance",
      is_sdc                   = "Yes",
      sdc_name                 = "sdc2",
      perf_profile_for_sdc     = "HighPerformance"
      perf_profile_for_sdc     = "HighPerformance",
      is_sdt                   = "Yes",
      sdt_name                 = "sdt2",
      sdt_all_ips              = "10.10.10.7,10.10.10.8",
    },
    {
      username                 = "user",
      password                 = "password",
      operating_system         = "linux",
      is_mdm_or_tb             = "TB",
      mdm_name                 = "tb1",
      mdm_ips                  = "10.10.10.9,10.10.10.10,10.01.10.11",
      mdm_mgmt_ip              = "10.10.10.9",
      perf_profile_for_mdm     = "HighPerformance",
      is_sds                   = "Yes",
      sds_name                 = "sds3",
      sds_all_ips              = "10.10.10.10,10.01.10.11",
      sds_storage_device_list  = "/dev/sdb",
      sds_storage_device_names = "sdb",
      protection_domain        = "domain_1",
      storage_pool_list        = "pool1",
      perf_profile_for_sds     = "HighPerformance",
      is_sdc                   = "Yes",
      sdc_name                 = "sdc3",
      perf_profile_for_sdc     = "HighPerformance"
      is_sdt                   = "Yes",
      sdt_name                 = "sdt3",
      sdt_all_ips              = "10.10.10.10,10.01.10.11",
    }
  ]

    storage_pools = [
    {
      media_type        = "SSD"
      protection_domain = "domain_1"
      storage_pool      = "pool1"
      daya_layout       = "MG"
      zero_padding      = "true"
    }
  ]
}

This Terraform configuration sets up a PowerFlex cluster having multiple values.

V1.9.0: Deploying a PowerFlex cluster using ssh key

Mon, 01 Jan 0001 00:00:00 +0000

Deploying a PowerFlex cluster using ssh key for passwordless authentication

This guide explains how to use ssh keys for deploying a cluster using passwordless authentication

Steps for configuring ssh key

On one of the ScaleIO cluster machine:
- Go to ~/.ssh
- ssh-keygen -t rsa
cat id_rsa.pub > authorized_keys
If the RSA key was created in OpenSSH key format convert to pem format:
- ssh-keygen -p -m PEM -f ~/.ssh/id_rsa
Copy the id_rsa, id_rsa.pub and authorized_keys to ~/.ssh on the rest of the cluster machines
Replace the key text in block-legacy-gateway-sshkey.yaml (attached below) with the content of id_rsa
Delete the secret before setting it:
- kubectl delete -n powerflex secret platform-nodes-credentials
run on the M&O:
- kubectl apply -n powerflex -f
delete block-legacy-gateway pod
- legacy_gw=$(kubectl get pods -n powerflex|grep -i legacy-gateway |grep -v mds |awk ‘{print $1}’); kubectl delete pods -n powerflex $legacy_gw
Remove the value (leave empty) from all the “password” fields in the csv file

Example of block-legacy-gateway-sshkey.yaml file content

apiVersion: v1 kind: Secret metadata: name: platform-nodes-credentials type: Opaque stringData: id_rsa: | —–BEGIN RSA PRIVATE KEY—– PASTE THE RSA KEY HERE —–END RSA PRIVATE KEY—–

Example of cluster resource in case of passwordless authentication

In this case just remove the password attribute from the cluster resource .


resource "powerflex_cluster" "test" {
  mdm_password = "Password"
  lia_password = "Password"

  # Advance Security Configuration
  allow_non_secure_communication_with_lia = false
  allow_non_secure_communication_with_mdm = false
  disable_non_mgmt_components_auth        = false

  # Cluster Configuration related fields
  cluster = [
    {
      # MDM Configuration Fields
      username                 = "user",
      operating_system         = "linux",
      is_mdm_or_tb             = "Primary",
      mdm_ips                  = "10.10.10.1",
      mdm_mgmt_ip              = "10.10.10.1",
      mdm_name                 = "mdm1",
      perf_profile_for_mdm     = "HighPerformance",
      is_sds                   = "Yes",
      sds_name                 = "sds1",
      sds_all_ips              = "10.10.10.1",
      protection_domain        = "domain_1",
      sds_storage_device_list  = "/dev/sdb",
      sds_storage_device_names = "sdb",
      storage_pool_list        = "pool1",
      perf_profile_for_sds     = "HighPerformance",
      is_sdc                   = "Yes",
      sdc_name                 = "sdc1",
      perf_profile_for_sdc     = "HighPerformance"

    },
    {
      username                 = "user",
      password                 = "password",
      operating_system         = "linux",
      is_mdm_or_tb             = "Secondary",
      mdm_name                 = "mdm2",
      mdm_ips                  = "10.10.10.2",
      mdm_mgmt_ip              = "10.10.10.2",
      perf_profile_for_mdm     = "HighPerformance",
      is_sds                   = "Yes",
      sds_name                 = "sds2",
      sds_all_ips              = "10.10.10.2",
      sds_storage_device_list  = "/dev/sdb",
      sds_storage_device_names = "sdb",
      protection_domain        = "domain_1",
      storage_pool_list        = "pool1",
      perf_profile_for_sds     = "HighPerformance",
      is_sdc                   = "Yes",
      sdc_name                 = "sdc2",
      perf_profile_for_sdc     = "HighPerformance"
    },
    {
      username                 = "user",
      password                 = "password",
      operating_system         = "linux",
      is_mdm_or_tb             = "TB",
      mdm_name                 = "tb1",
      mdm_ips                  = "10.10.10.3",
      mdm_mgmt_ip              = "10.10.10.3",
      perf_profile_for_mdm     = "HighPerformance",
      is_sds                   = "Yes",
      sds_name                 = "sds3",
      sds_all_ips              = "10.10.10.3",
      sds_storage_device_list  = "/dev/sdb",
      sds_storage_device_names = "sdb",
      protection_domain        = "domain_1",
      storage_pool_list        = "pool1",
      perf_profile_for_sds     = "HighPerformance",
      is_sdc                   = "Yes",
      sdc_name                 = "sdc3",
      perf_profile_for_sdc     = "HighPerformance"
    }
  ]

    storage_pools = [
    {
      media_type        = "SSD"
      protection_domain = "domain_1"
      storage_pool      = "pool1"
      daya_layout       = "MG"
      zero_padding      = "true"
    }
  ]
}

This Terraform configuration sets up a PowerFlex cluster without using password.

V1.9.0: Deploying a PowerFlex SDC using a CSV Topology File

Mon, 01 Jan 0001 00:00:00 +0000

Deploying a PowerFlex SDC using a CSV Topology File

This guide explains how to use a CSV file as input for an SDC Resource.

Example

Note: In the CSV file, provide only Cluster Node-related details as shown in the example below:

sdc_input.csv

IPs,Password,Operating System,Is MDM/TB,Is SDC,perfProfileForSDC,SDC Name
10.10.10.10,password,linux,Primary,Yes,HighPerformance,SDC1
10.10.10.11,password,linux,Secondary,Yes,HighPerformance,SDC2
10.10.10.12,password,linux,TB,Yes,Compact,SDC3
10.10.10.13,password,linux,Standby,Yes,Compact,SDC4

To perform SDC operations via CSV file(s), use the following configuration:


locals {
  csv_data = csvdecode(file("data/sdc_input.csv"))
}

resource "powerflex_sdc" "sdc_rs" {
  mdm_password = "MDM_Password"
  lia_password = "LIA_Password"

  sdc_details = [
    for row in local.csv_data : {
      ip                  = row.IPs # if using complere config use row["MDM IPs"]
      password            = row.Password
      operating_system    = row["Operating System"]
      is_mdm_or_tb        = row["Is MDM/TB"]
      is_sdc              = row["Is SDC"]
      name                = row["SDC Name"]
      performance_profile = row.perfProfileForSDC
    }
    if row.IPs != "" && row.IPs != "null" && row.Password != "null"
  ]
}

This code demonstrates how you can use data from the CSV file to dynamically configure the powerflex_sdc resource.

locals: This section defines local variables within the Terraform configuration. These variables are used to store data or perform calculations within your configuration.

csv_data: This is a local variable that is being assigned the result of csvdecode(file(“sdc_input.csv”)). It decodes the content of the “sdc_input.csv” file into a data structure that can be used in the Terraform configuration.

file("sdc_input.csv"): This part of the code specifies the path to the CSV file. In this example, it assumes that “sdc_input.csv” is located in the same directory as your Terraform configuration file. If the CSV file is in a different directory, you can provide the relative or absolute path to that file. For example, if the CSV file is in a subdirectory named “data,” you can specify the path as file(“data/sdc_input.csv”).

sdc_details: This is an attribute of the powerflex_sdc resource. You are using a list comprehension (the for loop) to create a list of objects based on the data from the CSV file (local.csv_data). Each object represents a configuration for an SDC (Storage Data Client).

The fields inside the object (e.g., ip, password, operating_system, etc.) are populated with values from the CSV file. You are also applying some conditions in the if statement to filter out rows where IPs and Password are not empty and not equal to “null.”

V1.9.0: Environment Variables

Mon, 01 Jan 0001 00:00:00 +0000

Environment Variables Overview

This Guide will describe two common ways on how to use environment variables with terraform. For more information you may check out the terraform docs directly.

Export or Directly Set During Terraform Command

This section will desribe how to pass in environment variables directly during the terraform command.

main.tf

// Create a variable which will be assigned during the command
variable "foo" {
  type = string
}

data "example_datasource" "all" {
  filter {
    // Reference that variable how you would normally in terraform 
    name = [var.foo]
  }
}

Using the above example, to set the environment variable for foo you must use the prefix of TF_VAR_ + the name of the variable i.e: TF_VAR_foo. This will translate to setting the variable during the command.

Example Command: TF_VAR_foo="example-name" terraform plan

Export and then run the terraform command

export TF_VAR_foo="example-name"

This will execute terraform plan with the value of example-name for the variable foo.

Using the External Terraform Provider

This section will describe how to use environment variables using the external terraform provider

env.sh

cat << EOF
{
 "foo": "test"
}
EOF

main.tf

terraform {
  required_providers {
    external = {
      source = "hashicorp/external"
      version = "2.3.4"
    }
  }
}

# Run the script to get the environment variables of interest.
# This is a datasource, so it will run at plan time.
data "external" "env" {
  program = ["bash", "env.sh"]
}

# Show the results of running the datasource. This is a map of environment
# variable names to their values.
output "env" {
  value = data.external.env.result
}

data "example_datasource" "all" {
  filter {
    name = [data.external.env.result["foo"]]
  }
}

In this example there are 2 files.

env.sh This creates the input for the environment variables you would like to pass into and use in the terraform configuration main.tf
main.tf this defines the external datasource which takes in the output from the external datasource and then it can be used in the example_datasource filter i.e data.external.env.result["foo"]

V1.9.0: Import existing volume mappings of SDC

Mon, 01 Jan 0001 00:00:00 +0000

Importing existing volume mappings of SDC using sdc_volumes_mapping resource

This guide explains how to import volumes mapped to SDC using sdc_volumes_mapping_resource. Below steps are taken from this article.

Step 1: Add the import block

    import {
        to = powerflex_sdc_volumes_mapping.test
        id = "sdc_id"
    }

Step 2: Plan and generate configuration

    terraform plan -generate-config-out=test.tf

Step 3: Review generated configuration in test.tf

Step 4: Run terraform apply to import the volumes mapped to SDC. Choose only one argument from mutually exclusive arguments.

For example, choose either volume_id or volume_name from sdc_volumes_mapping resource.

V1.9.0: Installing a SDC on a PowerFlex cluster using multiple values for IP

Mon, 01 Jan 0001 00:00:00 +0000

Installing a SDC on a PowerFlex cluster using multiple values for IP

This guide explains how to install a SDC in case of multiple values for IP.

Example

resource "powerflex_sdc" "sdc-example" {
  mdm_password = "Password
  lia_password = "Password"
  sdc_details = [
    {
      ip                  = "10.10.10.1,10.10.10.2,10.10.10.3" 
      username            = "user"
      password            = "password"
      operating_system    = "linux"
      is_mdm_or_tb        = "Primary"
      is_sdc              = "Yes"
      name                = "SDC_PRIMARY"
      performance_profile = "HighPerformance"
      virtual_ips         = "10.10.10.4,10.10.10.5"
      virtual_ip_nics     = "eth1,eth2"
      data_network_ip     = "10.10.10.2,10.10.10.3"
    },
    {
      ip                  = "10.10.10.6,10.10.10.7,10.10.10.8" 
      username            = "user"
      password            = "password"
      operating_system    = "linux"
      is_mdm_or_tb        = "Secondary"
      is_sdc              = "Yes"
      name                = "SDC_SECONDARY"
      performance_profile = "HighPerformance"
      virtual_ips         = "10.10.10.4,10.10.10.5"
      virtual_ip_nics     = "eth1,eth2"
      data_network_ip     = "10.10.10.7,10.10.10.8"
    },
    {
      ip                  = "10.10.10.9,10.10.10.10,10.10.10.11" 
      username            = "user"
      password            = "password"
      operating_system    = "linux"
      is_mdm_or_tb        = "TB"
      is_sdc              = "Yes"
      name                = "SDC_TB"
      performance_profile = "Compact"
      data_network_ip     = "10.10.10.10,10.10.10.11"
    },
    {
      ip               = "10.10.10.12"
      username         = "user"
      password         = "password"
      operating_system = "linux"
      is_mdm_or_tb     = "Standby"
      is_sdc           = "Yes"
    }
  ]
}

V1.9.0: Protecting Terraform Resources

Mon, 01 Jan 0001 00:00:00 +0000

Protecting Terraform Resources by Managing Resource Lifecycle

Terraform provides a lifecycle block within resource configurations to control the creation, update, and deletion of resources. This block is essential for managing resource behavior and ensuring critical resources are not accidentally destroyed.

Key Arguments in the lifecycle Block

prevent_destroy:

Prevents Terraform from destroying the resource. If a plan includes the destruction of this resource, Terraform will produce an error instead.

resource "powerflex_example" "example" {
  # ... other configuration ...

  lifecycle {
    prevent_destroy = true
  }
}

ignore_changes:

Ignores changes to specified attributes of the resource. This is useful when certain attributes are managed outside of Terraform.

resource "eg_instance" "example" {
  # ... other configuration ...

  lifecycle {
    ignore_changes = [
      tags,
    ]
  }
}

create_before_destroy:

Ensures that a new resource is created before the existing one is destroyed. This is useful in certain cases and for minimizing downtime.

resource "powerflex_example" "example" {
 # ... some other configuration ...

  lifecycle {
    create_before_destroy = true
  }
}

Example: Preventing Accidental Deletion

To ensure a critical resource, such as a volume instance, is not accidentally deleted, you can use the prevent_destroy argument:

resource "powerflex_volume" "example-volume-create" {
  name = "example-volume-create"
  protection_domain_name = "domain1"
  storage_pool_name = "pool1"

  # The unit of size of the volume is defined by capacity_unit whose default value is "GB".
  size          = 8
  capacity_unit = "GB" # GB/TB

  use_rm_cache = true
  volume_type  = "ThickProvisioned"      # ThickProvisioned/ThinProvisioned volume type
  access_mode  = "ReadWrite"             # ReadWrite/ReadOnly volume access mode
  remove_mode  = "INCLUDING_DESCENDANTS" # INCLUDING_DESCENDANTS/ONLY_ME remove mode
  lifecycle {
    prevent_destroy = true
  }
}

In this example, the prevent_destroy argument ensures that any attempt to destroy the powerflex_volume resource will result in an error, protecting it from accidental deletion.

Additional Resources

For more detailed information on the lifecycle block and its arguments, refer to the Terraform documentation on lifecycle meta-arguments